**Revit API Intro Labs**

**Lab 6 – Extensible Storage**

Created by A. Nagy, May 2011  
Updated by DevTech AEC WG  
Last modified:

**<VB.NET>**VB.NET Version**</VB.NET>**

**Objective:** In this lab, we will learn how to use Extensible Storage mechanism to add custom data to a Revit element. During the course of building a command, we’ll also cover Selection Filter and Transaction. We’ll learn how to:

* Define a storage data “Schema” and attach an instance of it to an Revit element
* Use an ISelectionFilter to limit the selection to Walls
* Use manual Transaction mode

**Tasks:** We’ll write a command that creates WallSocketLocation Schema with two Fields, SocketLocation and SocketNumber, and attach its Entity (or instance) to a wall.

1. Ask user to pick a wall
2. Create our Schema with the two Fields
3. Create an Entity of the schema and set its field values
4. Assign the entity to the wall using SetEntity()

The following is the breakdown of step by step instructions in this lab:

1. Define a New External Command with Manual Transaction Mode
2. Create a Selection Filter
3. Create and Attach a Schema Entity to a Wall
4. Summary
5. **Define a New External Command with Manual Transaction Mode**

We’ll add another external command to the current project.

* 1. Add a new file and define another external command to your project. Let’s name them as follows:
* File name: **6\_ExtensibleStorage.vb (or .cs)**
* Command class name: **ExtensibleStorage**

**Required Namespaces:**

In addition to the name spaces you have used, add the name space:

* Autodesk.Revit.DB.ExtensibleStorage

Below is the starting point of our new command. Notice that this time, we are using manual transaction:

**<VB.NET>**  
' Model Creation - learn how to create elements

<Transaction(TransactionMode.Manual)> \_

Friend Class ExtensibleStorage

Implements IExternalCommand

Public Function Execute( \_

ByVal commandData As ExternalCommandData, \_

ByRef message As String, \_

ByVal elements As ElementSet) \_

As Result \_

Implements IExternalCommand.Execute

Dim uiDoc As UIDocument = commandData.Application.ActiveUIDocument

Dim doc As Document = uiDoc.Document

' Create transaction for working with schema

Dim trans As New Transaction(doc, "Extensible Storage")

trans.Start()

' …

trans.Commit()

Return Result.Succeeded

End Function

End Class

**</VB.NET>**

1. **Create a Selection Filter**

Though this topic will be part of the UI Labs and that’s where its components will be explained, we’ll use PickObject() and ISelectionFilter in this lab as well. We simply need to create a class that implements the ISelectionFilter interface and its two functions: AllowElement() and AllowReference(). Let’s create it inside the ExtensibleStorage class:

**<VB.NET>**   
Private Class WallSelectionFilter

Implements ISelectionFilter

Public Function AllowElement(ByVal e As Element) As Boolean \_

Implements ISelectionFilter.AllowElement

Return TypeOf e Is Wall

End Function

Public Function AllowReference(ByVal r As Reference, ByVal p As XYZ) \_

As Boolean Implements ISelectionFilter.AllowReference

Return True

End Function

End Class

**</VB.NET>**

Now we’ll be able to use an instance of this class when asking the user to pick an element in the user interface to restrict the selection to only walls.

Let’s ask the user to pick a wall, to which we want to add data, and then get back the wall from the returned Reference:

**<VB.NET>**

' Pick a wall

Dim r As Reference = uiDoc.Selection.PickObject( \_

ObjectType.Element, New WallSelectionFilter)

Dim wall As Wall = TryCast(doc.GetElement(r), Wall)

**</VB.NET>**

1. **Create a Schema and Attach an Entity to a Wall**

To create a Schema, we use the SchemaBuilder object, which requires a GUID that will identify the schema later on. So let’s declare this GUID in our ExtensibleStorage class:

**<VB.NET>**

Private \_guid As Guid = New Guid("87aaad89-6f1b-45e1-9397-2985e1560a02")

**</VB.NET>**

Note: you could generate and use another GUID as well, using Visual Studio’s ‘Tools >> Generate GUID’ function.

Let’s start building our schema by creating a new SchemaBuilder instance and set its properties. We’ll set the Read and Write access levels to public. If we set it to Vendor or Application then we would also need to specify the vendor id for the schema using SetVendorId(). The vendor id is the Registered Developer Symbol (RDS) that can be created on this site:

<http://www.autodesk.com/symbreg>

Since vendor ids are not case sensitive, the string will be converted to upper case before it is stored in the schema.

**<VB.NET>**

' Create a scheme builder

Dim builder As New SchemaBuilder(\_guid)

' Set read and write access levels

builder.SetReadAccessLevel(AccessLevel.Public)

builder.SetWriteAccessLevel(AccessLevel.Public)

' Note: if this was set as vendor or application access,

' we would have been additionally required to use SetVendorId

' Set name to this schema builder

builder.SetSchemaName("WallSocketLocation")

builder.SetDocumentation("Data store for socket info in a wall")

**</VB.NET>**

Add two fields to the schema. One will contain a location property and will be of type XYZ, and the other one will contain the id number of our socket, and will be of type string.

Once these are added we can call Finish() to create the Schema object.

**<VB.NET>**

' Create field1

Dim fieldBuilder1 As FieldBuilder = \_

builder.AddSimpleField("SocketLocation", GetType(XYZ)). \_

SetUnitType(UnitType.UT\_Length)

' Set unit type

fieldBuilder1.SetUnitType(UnitType.UT\_Length)

' Add documentation (optional)

' Create field2

Dim fieldBuilder2 As FieldBuilder = \_

builder.AddSimpleField("SocketNumber", GetType(String))

'fieldBuilder2.SetUnitType(UnitType.UT\_Custom);

' Register the schema object

Dim schema As Schema = builder.Finish

**</VB.NET>**

Now we can create two Entity’s based on our Schema and assign them to the selected wall.

**<VB.NET>**

' Create an entity (object) for this schema (class)

Dim ent As New Entity(schema)

Dim socketLocation As Field = schema.GetField("SocketLocation")

ent.Set(Of XYZ)(socketLocation, New XYZ(2, 0, 0), \_

DisplayUnitType.DUT\_METERS)

Dim socketNumber As Field = schema.GetField("SocketNumber")

ent.Set(Of String)(socketNumber, "200")

wall.SetEntity(ent)

' Now create another entity (object) for this schema (class)

' (This simply replaces the ent1 above. Just for testing.

' You may comment out for now.)

Dim ent2 As New Entity(schema)

Dim socketNumber1 As Field = schema.GetField("SocketNumber")

ent2.Set(Of String)(socketNumber1, "400")

wall.SetEntity(ent2)

**</VB.NET>**

We could also list all the available Schema’s and the Fields available in our schema just to see if everything went the way we wanted it.

**<VB.NET>**

' List all schemas in the document

Dim s As String = String.Empty

Dim schemas As IList(Of Schema) = schema.ListSchemas

Dim sch As Schema

For Each sch In schemas

s += vbCrLf + "Schema name: " + sch.SchemaName

Next

TaskDialog.Show("Schema details", s)

' List all Fields for our schema

s = String.Empty

Dim fields As IList(Of Field) = schema.Lookup(\_guid).ListFields

Dim fld As Field

For Each fld In fields

s += vbCrLf + "Field name: " + fld.FieldName

Next

TaskDialog.Show("Field details", s)

**</VB.NET>**

Now let’s check if the Entity’s we assigned to the selected wall can be accessed all right.

**<VB.NET>**

' Extract the value for the field we created

Dim wallSchemaEnt As Entity = wall.GetEntity(schema.Lookup(\_guid))

Dim wallSocketPos As XYZ = wallSchemaEnt.Get(Of XYZ)( \_

schema.Lookup(\_guid).GetField("SocketLocation"), \_

DisplayUnitType.DUT\_METERS)

s = "SocketLocation: " + PointToString(wallSocketPos)

Dim wallSocketNumber As String = wallSchemaEnt.Get(Of String)( \_

schema.Lookup(\_guid).GetField("SocketNumber"))

s += vbCrLf + "SocketNumber: " + wallSocketNumber

TaskDialog.Show("Field Values", s)

**</VB.NET>**

Where PointToString() is a simple helper function to convert a point as a string for display. You may reuse the one you have written in Lab2, e.g.:

**<VB.NET>**

'' Helper Function: returns XYZ in a string form.

''

Public Shared Function PointToString(ByVal pt As XYZ) As String

If pt Is Nothing Then

Return ""

End If

Return "(" + pt.X.ToString("F2") + ", " + pt.Y.ToString("F2") + \_

", " + pt.Z.ToString("F2") + ")"

End Function

**</VB.NET>**

1. **Summary**

In this lab, we learned how to define and attach a custom data to a Revit element, using Extensible Storage mechanism in the API. We have learned how to:

* Create and access extensible storage entities of Revit elements.

Autodesk Developer Network